Click read more to see the script

The Script

' -------------------------------
' Name    : Compare Folder Script
' Version : 1.0
' Author  : Lucky
' -------------------------------

WScript.Echo "Compare Folder Script v1.0 by Lucky"
WScript.Echo "==================================="
WScript.Echo

Dim args
Set args = WScript.Arguments

Dim folder1
Dim folder2
Dim hideok

If args.Count<>3 Then
    WScript.Echo "Usage: cscript compare.vbs [folder1] [folder2] [hideok]"
    WScript.Quit()
Else
    folder1=args(0)
    folder2=args(1)
    If LCase(args(2)) = "yes" Then
        hideok = True
    Else
    	  hideok = False
    End If
    WScript.Echo "Compare """ & args(0) & """ and """ & args(1) & """:"
    WScript.Echo
End If

'Start compare
Function comparefolder(folder1,folder2,hideok)
	Dim fso,f1

	Set fso = CreateObject("Scripting.FileSystemObject")
	Set f1 = fso.GetFolder(folder1)
	Set f2 = fso.GetFolder(folder2)

	'Check on first folder
	Set colFiles = f1.Files
	For Each objFile in colFiles
	    cmpFileName = fso.BuildPath(f2.Path, objFile.Name)

	    If fso.FileExists(cmpFileName) Then
	        Set objFile2 = fso.GetFile(cmpFileName)
                IsOk= True
	        If objFile.Size <> objFile2.Size Then
	            WScript.Echo objFile.Path + ": Different file size (" + CStr(objFile.Size) + " and " + CStr(objFile2.Size) + ")"
                    IsOk = False
	        End If
	        If objFile.DateLastModified <> objFile2.DateLastModified Then
	            WScript.Echo objFile.Path + ": Different modified date (" + CStr(objFile.DateLastModified) + " and " + CStr(objFile2.DateLastModified) + ")"
                    IsOk = False
                End If
	        If Not hideok And IsOk Then
	            WScript.Echo objFile.Path + ": OK"
	        End If
	    Else
	        WScript.Echo cmpFileName + ": file didn't exist"
	    End If
	Next

	'Check on second folder
	Set colFiles = f2.Files
	For Each objFile in colFiles
	    cmpFileName = fso.BuildPath(f1.Path, objFile.Name)

	    If Not fso.FileExists(cmpFileName) Then
	        WScript.Echo cmpFileName + ": file didn't exist"
	    End If
	Next

	'Check on first folder sub
	Set colFolders = f1.SubFolders
	For Each objFolder in colFolders
	    cmpFolderName = fso.BuildPath(f2.Path, objFolder.Name)

	    If fso.FolderExists(cmpFolderName) Then
          Call comparefolder(objFolder.Path,cmpFolderName,hideok)
	    Else
	        WScript.Echo cmpFolderName + ": folder didn't exist"
	    End If

	Next

	'Check on second folder sub
	Set colFolders = f2.SubFolders
	For Each objFolder in colFolders
	    cmpFolderName = fso.BuildPath(f1.Path, objFolder.Name)

	    If Not fso.FolderExists(cmpFolderName) Then
	        WScript.Echo cmpFolderName + ": folder didn't exist"
	    End If

	Next
End Function

Call comparefolder(folder1,folder2,hideok)

WScript.Quit()

Usage
Copy the script above and save it to file named “compare.vbs”.

Syntax:
cscript compare.vbs [folder1] [folder2] [hideok]

Examples:
Compare folder named "folder1" to "folder2" and hide indentical file.
cscript compare.vbs "folder1" "folder2" yes

Compare folders and save the report to file
cscript compare.vbs "folder1" "folder2" no > differences.txt

No related posts.

What is Regular Expression?
Basically, a regular expression is a pattern describing a certain amount of text. Their name comes from the mathematical theory on which they are based. But we will not dig into that. Since most people including myself are lazy to type, you will usually find the name abbreviated to regex or regexp. I prefer regex, because it is easy to pronounce the plural “regexes”.

Click read more to see the script

The Script

' ----------------------------------
' Name    : Regex Rename File Script
' Version : 1.0
' Author  : Lucky
' ----------------------------------

WScript.Echo "Rename File Script v1.0 by Lucky"
WScript.Echo "================================"
WScript.Echo

Dim args
Set args = WScript.Arguments

Dim pattern
Dim replacement

If args.Count<>2 Then
    WScript.Echo "Usage: cscript rename.vbs [searchpattern] [replacement]"
    WScript.Quit()
Else
    pattern=args(0)
    replacement=args(1)
    WScript.Echo "Replace """ & args(0) & """ to """ & args(1) & """:"
    WScript.Echo
End IF

'Start rename
Dim fso,cf,regex
Dim oldname,newname
Dim matches

Set fso = CreateObject("Scripting.FileSystemObject")
Set cf = fso.GetFolder(".")
Set regex = New RegExp
regex.Pattern=pattern
regex.IgnoreCase=True

Set colFiles = cf.Files
For Each objFile in colFiles
    oldname=objFile.Name
    Set matches = regex.Execute(oldname)
    If matches.Count>0 Then
        newname=regex.Replace(oldname,replacement)
        Wscript.Echo "Rename """ & oldname & """ to """ & newname & """"
        objFile.Move newname
    End If

Next

Usage
First you need to copy the script above and paste it on notepad, save it to “rename.vbs”. Regex rename script needs two parameters, pattern and replacement. The script will find matching filename with the pattern in current folder, and replace it to replacement text.

Usage: cscript rename.vbs [searchpattern] [replacement]

Examples
You can use a few examples with the script

#simply rename a file from image.jpg to image2.jpg
cscript rename.vbs image.jpg image2.jpg

#rename some file with wildcards, image?.jpg to picture?.jpg
cscript rename.vbs image(.).jpg picture$1.jpg

#another example with wildcards, rename file start with image to picture
cscript rename.vbs image(.*) picture$1

Limitation
Currently the latest VBScript version 5.5 regular expression engine has some limitation, which are:

• No \A or \Z anchors to match the start or end of the string. Use a caret or dollar instead
• Lookbehind is not supported at all. Lookahead is fully supported
• No atomic grouping or possessive quantifiers
• No Unicode support, except for matching single characters with \uFFFF
• No named capturing groups. Use numbered capturing groups instead
• No mode modifiers to set matching options within the regular expression
• No conditionals
• No regular expression comments. Describe your regular expression with VBScript apostrophe comments instead, outside the regular expression string

Source: Regular-Expression.info

No related posts.

Requirement
In order to run the script, you must first download the CDDBControl.dll library file. You can download it here.

Note: it also support WMA format

Click read more to see details.

Installation
After you downloaded it, extract to C:\Windows\System32, and run this command:

C:\Windows\System32\regsvr32 CDDBControl.dll

The Script
Here is an example vb script to read mp3 and wma files in current folder.

'Read ID3Tags
Sub ReadID3Tags(folderPath)
  'create FileSystemObject instance
  Dim fso
  Set fso = CreateObject("Scripting.FileSystemObject")
  Dim folder
  Set folder = fso.GetFolder(folderPath)
  Dim thefile,ext
  Dim id3obj
  Set id3obj = CreateObject("CDDBControl.CddbID3Tag")

  'enumerate files in the folder
  For Each thefile In folder.Files
    'select only mp3 And wma files
    ext = LCase(Right(thefile.Name, 4))
    If ext=".mp3" Or ext=".wma" Then
      'load file
      id3obj.LoadFromFile thefile.Path, True 'set false if you want to read
      WScript.Echo thefile.Name
      WScript.Echo "Album		: " & id3obj.Album
      WScript.Echo "Movie		: " & id3obj.Movie
      WScript.Echo "Title		: " & id3obj.Title
      WScript.Echo "CopyrightYear	: " & id3obj.CopyrightYear
      WScript.Echo "CopyrightHolder	: " & id3obj.CopyrightHolder
      WScript.Echo "Comments	: " & id3obj.Comments
      WScript.Echo "Label		: " & id3obj.Label
      WScript.Echo "BeatsPerMinute	: " & id3obj.BeatsPerMinute
      WScript.Echo "LeadArtist	: " & id3obj.LeadArtist
      WScript.Echo "PartOfSet	: " & id3obj.PartOfSet
      WScript.Echo "TrackPosition	: " & id3obj.TrackPosition
      WScript.Echo "Year		: " & id3obj.Year
      WScript.Echo "Genre		: " & id3obj.Genre
      WScript.Echo "FileId		: " & id3obj.FileId
      WScript.Echo "ISRC		: " & id3obj.ISRC
      WScript.Echo
    End If
  Next
End Sub

'Call the function
ReadID3Tags(".")

Usage
Save the script above, save it to readid3files.vbs, put it on a folder where you keep your mp3 files. Run the command below:

cscript readid3files.vbs

Another Functions
Here is full list functions of the library.

Interfaces:
Interface ICddbID3Tag
GUID: {0306D2A8-B7E2-4EA2-ADC6-78F80D65B1E2}
HelpString: ICddbID3Tag Interface
# Members: Sub QueryInterface(riid as GUID, ppvObj as Void)
# Function AddRef as VT_UI4
# Function Release as VT_UI4
# Sub GetTypeInfoCount(pctinfo as VT_UINT)
# Sub GetTypeInfo(itinfo as VT_UINT, lcid as VT_UI4, pptinfo as Void)
# Sub GetIDsOfNames(riid as GUID, rgszNames as VT_I1, cNames as VT_UINT, lcid as VT_UI4, rgdispid as Long)
# Sub Invoke(dispidMember as Long, riid as GUID, lcid as VT_UI4, wFlags as VT_UI2, pdispparams as DISPPARAMS, pvarResult as Variant, pexcepinfo as EXCEPINFO, puArgErr as VT_UINT)
# Property Get Album as String [property Album]
# Property Put Album as String [property Album]
# Property Get Movie as String [property Movie]
# Property Put Movie as String [property Movie]
# Property Get Title as String [property Title]
# Property Put Title as String [property Title]
# Property Get CopyrightYear as String [property CopyrightYear]
# Property Put CopyrightYear as String [property CopyrightYear]
# Property Get CopyrightHolder as String [property CopyrightHolder]
# Property Put CopyrightHolder as String [property CopyrightHolder]
# Property Get Comments as String [property Comments]
# Property Put Comments as String [property Comments]
# Property Get Label as String [property Label]
# Property Put Label as String [property Label]
# Property Get BeatsPerMinute as String [property BeatsPerMinute]
# Property Put BeatsPerMinute as String [property BeatsPerMinute]
# Property Get LeadArtist as String [property LeadArtist]
# Property Put LeadArtist as String [property LeadArtist]
# Property Get PartOfSet as String [property PartOfSet]
# Property Put PartOfSet as String [property PartOfSet]
# Property Get TrackPosition as String [property TrackPosition]
# Property Put TrackPosition as String [property TrackPosition]
# Property Get Year as String [property Year]
# Property Put Year as String [property Year]
# Property Get Genre as String [property Genre]
# Property Put Genre as String [property Genre]
# Property Get FileId as String [property FileId]
# Property Put FileId as String [property FileId]
# Property Get ISRC as String [property ISRC]
# Property Put ISRC as String [property ISRC]
# Sub LoadFromFile(Filename as String, Readonly as Long) [method LoadFromFile]
# Sub BindToFile(Filename as String, Readonly as Long) [method BindToFile]
# Sub SaveToFile(Filename as String) [method SaveToFile]
# Sub Commit [method Commit]
# Sub Clear [method Clear]
# Sub LoadFromBuffer(Buffer as Variant, BufferSize as Long) [method LoadFromBuffer]
# Function GetBufferSize as Long [method GetBufferSize]
# Sub SaveToBuffer(Buffer as Variant, BufferSize as Long) [method SaveToBuffer]
# Function GetTextFrame(Frame as String) as String [method GetTextFrame]
# Sub SetTextFrame(Frame as String, Text as String) [method SetTextFrame]

Source: Motobit

No related posts.

• Right click on My Computer, choose Manage
• Expand tree Services and Applications
• If you see Internet Information Services item, then your IIS service is already installed

IIS Installation
To install IIS Service, follow these instructions to activate it:

• Go to Control Panel > Add or Remove Programs
• Open Add/Remove Windows Components, tick on Internet Information Services (IIS)
• Click Next button until it finished

Create a Virtual Server
Check on the Web Sites folder in IIS management console, you may see only “Default Web Site”. If you are a web developer, sometime you need to have another separate web servers. Of course you can also mount a virtual directory to the server, but it will never have root path.

Now you can add another virtual servers which have it’s own root path. IIS have a collection of scripts for administrative tasks such as creating another virtual servers. You can found the scripts on C:\Inetpub\AdminScripts, to create a virtual server we can use script file adsutil.vbs. For details, follow instructions below:

• Open command prompt, click on Start menu > Run, type cmd and press enter
• Go to the scripts folder, type “cd \Inetpub\AdminScripts”
• Create new virtual server and copy all the necessary settings using these commands

   cscript adsutil.vbs create_vserv W3SVC/2
   cscript adsutil.vbs copy W3SVC/1 W3SVC/2
  

• Now you should create a folder for the web’s home directory, for example C:\Inetpub\wwwroot_secondary
• Go back to IIS Management Console, you should see another Web inside Web Sites folder
• If you see red icon for the new web, don’t worry it’s normal, Windows tried to start the second web, unfortunately you can only run one at a time
• Rename it, right click on Second web, choose rename, type “Secondary Web” for example

Switch The Virtual Server
To switch the running server, you can make batch file running these command:

enable_second_server.bat
cscript C:\Inetpub\AdminScripts\adsutil.vbs STOP_SERVER W3SVC/1
cscript C:\Inetpub\AdminScripts\adsutil.vbs START_SERVER W3SVC/2

enable_first_server.bat
cscript C:\Inetpub\AdminScripts\adsutil.vbs STOP_SERVER W3SVC/2
cscript C:\Inetpub\AdminScripts\adsutil.vbs START_SERVER W3SVC/1

Delete a Virtual Server
To delete you previously created, use this command:

C:\Inetpub\AdminScripts>cscript adsutil.vbs delete W3SVC/2

No related posts.

1. Using IE Instance
The first method using IE instance
pros:

• No need to install
• You can see the progress by uncomment set visible line

cons:

• IE doesnt have method to let you wait until finish, so you must check in a loop
• IE takes more memory than other methods

Function IEGetRequest(URL)
  'Create IE Instance
  Dim IeInstance

  Set IeInstance = CreateObject("InternetExplorer.Application")

  'Uncomment the next line to see IE window
  'IeInstance.Visible = True

  IeInstance.Navigate URL

  Do While IeInstance.Busy
    Wait 1, "Waiting " & URL
  Loop

  'Get the response
  On Error Resume Next
  IEGetRequest = IeInstance.Document.Body.innerHTML
  IeInstance.Quit
End Function

Sub Wait(sec, msg)
  On Error Resume Next
  Dim Shell
  If IsEmpty(Shell) Then
    Set Shell = CreateObject("WScript.Shell")
  End If
  Shell.Popup msg, sec, "", 64
End Sub

' Test the function
MsgBox IEGetRequest("http://www.yahoo.com/")

2. Using HttpRequest Object
The second method is using HttpRequest object. There are several objects we can use.

1. XMLHTTP. First http request object from Microsoft work with VBS/ASP/WSH. This object uses WinInet API (not suitable for use in ASP apps)
2. ServerXMLHTTP. This object was created because of problems with XMLHTTP in server applications. It contains its own http engine, which is safe to use in server applications. The http engine has some small limitations (I think it does not enable client certificates, etc.), but the limitations has probably no impact to usual demands.
3. WinHTTP object. Similar as ServerXMLHTTP You can find the object at http://msdn.microsoft.com, search for WinHTTP.

My recomendation – use this object, if you can install it. MSXML 4.0 package uses this library also (see http://msdn.microsoft.com/library/default.asp?url=/library/en-us/xmlsdk/htm/sdk_dependencies_9po5.asp)

These three objects has almost the same OLE interface, so you can use the same source code.

Function HttpGetRequest(URL)
  Dim req

  'Create request object, you can use one of these object
  Set req = CreateObject("MSXML2.XMLHTTP")
  'Set req = CreateObject("MSXML2.ServerXMLHTTP")
  'Set req = CreateObject("WinHttp.WinHttprequest.5")

  'Open URL as GET request, the third parameter means that it should wait until finish before continue
  req.Open "GET", URL, False

  'Send the request (we dont need to use the parameter)
  req.send vbNullString

  'Get the result string
  HttpGetRequest = req.responseText
End Function

'Test function
MsgBox HttpGetRequest("http://www.yahoo.com/")

No related posts.